Intial commit

PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Fabian <fabian@ldsoft.dev>
+pkgname=cuetools
+pkgver=269.5d7208b
+pkgrel=1
+pkgdesc="Cue and toc file parsers and utilities"
+arch=('x86_64')
+url="https://git.ldsoft.dev/fabs/cuetools.git"
+#url="http://developer.berlios.de/projects/cuetools/"
+license=('GPL')
+depends=('glibc')
+optdepends=("id3v2: mp3 support in cuetag (does not require mutagen)"
+            "mutagen-tools: mp3 support in cuetag (does not require id3v2)")
+
+source=("$pkgname"::"git+https://git.ldsoft.dev/fabs/cuetools.git")
+sha512sums=('SKIP')
+
+pkgver () {
+  cd ${pkgname}
+#  sed -nE '/^VERSION\ [0-9.]*(-git|)$/p' configure.acr|grep -o '[0-9.]*'|tr -d '\n'
+  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+
+prepare() {
+  cd "$srcdir/$pkgname"
+
+  aclocal
+  autoheader
+  automake --force-missing --add-missing
+  autoconf
+}
+
+build() {
+  cd "$srcdir/$pkgname"
+
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname"
+
+  make DESTDIR="$pkgdir" install
+}